15.4.2 Aantal cliënten met een Wlz-indicatie per sector

Concepten

• Bedrijf
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.2
2# Parameters: ?peildatum 
3# Ontologie: versie 2.0.0 of nieuwer
4
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
11PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
12
13SELECT ?Organisatieonderdeel        
14        (SUM(?vv) as ?aantal_vv)
15        (SUM(?lg) as ?aantal_lg)
16        (SUM(?lvg) as ?aantal_lvg)
17        (SUM(?vg) as ?aantal_vg)
18        (SUM(?zgaud) as ?aantal_zgaud)
19        (SUM(?zgvis) as ?aantal_zgvis)
20        (SUM(?ggzb) as ?aantal_ggzb)
21        (SUM(?ggzw) as ?aantal_ggzw)  
22
23WHERE
24{
25    #BIND ($(peildatum) AS ?peildatum)
26    
27    ?indicatie
28        a onz-zorg:WlzIndicatie ;
29        onz-g:isAbout ?client ;
30        onz-g:hasPart/onz-g:isAbout ?sector ;
31        onz-g:startDatum ?start_indicatie .
32        OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
33        FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
34    
35    ?sector
36            a onz-zorg:LangdurigeZorgSector .
37    ?client
38        a onz-g:Human .
39    
40    # Koppel een zorgproces aan de Wlz indicaties en locaties
41    ?zorgproces a onz-g:CureAndCareProcess ;
42                onz-g:definedBy ?indicatie ;
43                onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie .
44
45    # Locatie en vestiging structuur
46    ?locatie 
47        a onz-g:StationaryArtifact ;
48        onz-g:partOf* ?vestiging_uri .
49    
50    ?vestiging_uri a onz-org:Vestiging ;
51        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
52    
53    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
54    
55    ?pc_gebied 
56        onz-g:identifiedBy ?postcode ;
57        onz-g:partOf+ ?zk_regio .
58    ?zk_regio a onz-org:ZorgkantoorRegio .
59    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
60
61    {     
62        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
63        ?vest_nr a onz-org:Vestigingsnummer ;
64            onz-g:hasDataValue ?vestiging .
65        BIND(?vestiging AS ?Organisatieonderdeel)
66    } UNION {
67        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
68        ?organisatie_uri 
69            a onz-g:Business ;
70            rdfs:label ?Organisatie .
71        BIND(CONCAT('Totaal ',?Organisatie) AS ?Organisatieonderdeel)
72        BIND("n.v.t." AS ?zk_vestiging)
73    }
74    
75    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
76
77    #Per financieringsstroom
78    BIND(IF(?sector = onz-zorg:VV, 1, 0) AS ?vv)
79    BIND(IF(?sector = onz-zorg:LG, 1, 0) AS ?lg)
80    BIND(IF(?sector = onz-zorg:LVG, 1, 0) AS ?lvg)
81    BIND(IF(?sector = onz-zorg:VG, 1, 0) AS ?vg)
82    BIND(IF(?sector = onz-zorg:ZGAUD, 1, 0) AS ?zgaud)
83    BIND(IF(?sector = onz-zorg:ZGVIS, 1, 0) AS ?zgvis)
84    BIND(IF(?sector = onz-zorg:GGZ-B, 1, 0) AS ?ggzb)
85    BIND(IF(?sector = onz-zorg:GGZ-W, 1, 0) AS ?ggzw)
86}
87GROUP BY ?Organisatieonderdeel
88ORDER BY ?Organisatieonderdeel
89